# Maintainer: Jesus Alvarez <jeezusjr at gmail dot com>
# Contributor: Kyle Fuller <inbox at kylefuller dot co dot uk>

pkgname=("zfs-utils")
pkgver=0.6.1_3.10.5
pkgrel=1
pkgdesc="Kernel module support files for the Zettabyte File System."
depends=("spl=0.6.1_3.10.5-1" "linux=3.10.5-1")
makedepends=("linux-headers=3.10.5-1")
arch=("i686" "x86_64")
url="http://zfsonlinux.org/"
source=(http://archive.zfsonlinux.org/downloads/zfsonlinux/zfs/zfs-0.6.1.tar.gz
        zfs-utils.bash-completion
        zfs-utils.initcpio.install
        zfs-utils.initcpio.hook
        zfs-utils.service
        zfs_git_head.patch)
groups=("archzfs")
md5sums=('822cd73c139d89369d6c3944f8afe659'
         '3e1c4a29c4f7d590e6a3041f2c61d6ff'
         'ebea2b1e593a9a19efa0f7ae7451bbc7'
         '8eec7f96316c7a1b6eeda8d56266a935'
         '2dd798467cfe03aa4532399b86d76300'
         'c99b1ce589cc409ffd18ef8db33da289')
license=("CDDL")

prepare() {
  cd "$srcdir/zfs-0.6.1"
  patch -Np1 -i ../zfs_git_head.patch
}

build() {
  cd "$srcdir/zfs-0.6.1"
  ./autogen.sh
  ./configure --prefix=/usr \
              --sysconfdir=/etc \
              --sbindir=/usr/bin \
              --libdir=/usr/lib \
              --datadir=/usr/share \
              --includedir=/usr/include \
              --with-udevdir=/lib/udev \
              --libexecdir=/usr/lib/zfs-0.6.1 \
              --with-config=user
  make
}

package() {
  cd "$srcdir/zfs-0.6.1"
  make DESTDIR="$pkgdir" install

  # Remove uneeded files
  rm -r $pkgdir/etc/init.d
  rm -r $pkgdir/usr/lib/dracut

  # move module tree /lib -> /usr/lib
  cp -r $pkgdir/{lib,usr}
  rm -r $pkgdir/lib

  # Fixup path
  mv $pkgdir/sbin/mount.zfs $pkgdir/usr/bin/
  rm -r $pkgdir/sbin

  install -D -m644 $srcdir/zfs-utils.initcpio.hook $pkgdir/usr/lib/initcpio/hooks/zfs
  install -D -m644 $srcdir/zfs-utils.initcpio.install $pkgdir/usr/lib/initcpio/install/zfs
  install -D -m644 $srcdir/zfs-utils.service $pkgdir/usr/lib/systemd/system/zfs.service
  install -D -m644 $srcdir/zfs-utils.bash-completion $pkgdir/usr/share/bash-completion/completions/zfs
}