You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
87 lines
2.9 KiB
87 lines
2.9 KiB
4 years ago
|
// SPDX-License-Identifier: MIT
|
||
|
|
|
||
|
|
pragma solidity >=0.6.0 <0.8.0;
|
||
|
|
|
||
|
|
import "./Proxy.sol";
|
||
|
|
import "../utils/Address.sol";
|
||
|
|
import "./IBeacon.sol";
|
||
|
|
|
||
|
|
/**
|
||
|
|
* @dev This contract implements a proxy that gets the implementation address for each call from a {UpgradeableBeacon}.
|
||
|
|
*
|
||
|
|
* The beacon address is stored in storage slot `uint256(keccak256('eip1967.proxy.beacon')) - 1`, so that it doesn't
|
||
|
|
* conflict with the storage layout of the implementation behind the proxy.
|
||
|
|
*/
|
||
|
|
contract BeaconProxy is Proxy {
|
||
|
|
/**
|
||
|
|
* @dev The storage slot of the UpgradeableBeacon contract which defines the implementation for this proxy.
|
||
|
|
* This is bytes32(uint256(keccak256('eip1967.proxy.beacon')) - 1)) and is validated in the constructor.
|
||
|
|
*/
|
||
|
|
bytes32 private constant _BEACON_SLOT = 0xa3f0ad74e5423aebfd80d3ef4346578335a9a72aeaee59ff6cb3582b35133d50;
|
||
|
|
|
||
|
|
/**
|
||
|
|
* @dev Initializes the proxy with `beacon`.
|
||
|
|
*
|
||
|
|
* If `data` is nonempty, it's used as data in a delegate call to the implementation returned by the beacon. This
|
||
|
|
* will typically be an encoded function call, and allows initializating the storage of the proxy like a Solidity
|
||
|
|
* constructor.
|
||
|
|
*
|
||
|
|
* Requirements:
|
||
|
|
*
|
||
|
|
* - `beacon` must be a contract with the interface {IBeacon}.
|
||
|
|
*/
|
||
|
|
constructor(address beacon, bytes memory data) public payable {
|
||
|
|
assert(_BEACON_SLOT == bytes32(uint256(keccak256("eip1967.proxy.beacon")) - 1));
|
||
|
|
_setBeacon(beacon, data);
|
||
|
|
}
|
||
|
|
|
||
|
|
/**
|
||
|
|
* @dev Returns the current beacon address.
|
||
|
|
*/
|
||
|
|
function _beacon() internal view returns (address beacon) {
|
||
|
|
bytes32 slot = _BEACON_SLOT;
|
||
|
|
// solhint-disable-next-line no-inline-assembly
|
||
|
|
assembly {
|
||
|
|
beacon := sload(slot)
|
||
|
|
}
|
||
|
|
}
|
||
|
|
|
||
|
|
/**
|
||
|
|
* @dev Returns the current implementation address of the associated beacon.
|
||
|
|
*/
|
||
|
|
function _implementation() internal view override returns (address) {
|
||
|
|
return IBeacon(_beacon()).implementation();
|
||
|
|
}
|
||
|
|
|
||
|
|
/**
|
||
|
|
* @dev Changes the proxy to use a new beacon.
|
||
|
|
*
|
||
|
|
* If `data` is nonempty, it's used as data in a delegate call to the implementation returned by the beacon.
|
||
|
|
*
|
||
|
|
* Requirements:
|
||
|
|
*
|
||
|
|
* - `beacon` must be a contract.
|
||
|
|
* - The implementation returned by `beacon` must be a contract.
|
||
|
|
*/
|
||
|
|
function _setBeacon(address beacon, bytes memory data) internal {
|
||
|
|
require(
|
||
|
|
Address.isContract(beacon),
|
||
|
|
"BeaconProxy: beacon is not a contract"
|
||
|
|
);
|
||
|
|
require(
|
||
|
|
Address.isContract(IBeacon(beacon).implementation()),
|
||
|
|
"BeaconProxy: beacon implementation is not a contract"
|
||
|
|
);
|
||
|
|
bytes32 slot = _BEACON_SLOT;
|
||
|
|
|
||
|
|
// solhint-disable-next-line no-inline-assembly
|
||
|
|
assembly {
|
||
|
|
sstore(slot, beacon)
|
||
|
|
}
|
||
|
|
|
||
|
|
if (data.length > 0) {
|
||
|
|
Address.functionDelegateCall(_implementation(), data, "BeaconProxy: function call failed");
|
||
|
|
}
|
||
|
|
}
|
||
|
|
}
|