You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
111 lines
4.5 KiB
111 lines
4.5 KiB
// SPDX-License-Identifier: MIT
|
|
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Base64.sol)
|
|
|
|
pragma solidity ^0.8.20;
|
|
|
|
/**
|
|
* @dev Provides a set of functions to operate with Base64 strings.
|
|
*/
|
|
library Base64 {
|
|
/**
|
|
* @dev Base64 Encoding/Decoding Table
|
|
* See sections 4 and 5 of https://datatracker.ietf.org/doc/html/rfc4648
|
|
*/
|
|
string internal constant _TABLE = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/";
|
|
string internal constant _TABLE_URL = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789-_";
|
|
|
|
/**
|
|
* @dev Converts a `bytes` to its Bytes64 `string` representation.
|
|
*/
|
|
function encode(bytes memory data) internal pure returns (string memory) {
|
|
return _encode(data, _TABLE, true);
|
|
}
|
|
|
|
/**
|
|
* @dev Converts a `bytes` to its Bytes64Url `string` representation.
|
|
*/
|
|
function encodeURL(bytes memory data) internal pure returns (string memory) {
|
|
return _encode(data, _TABLE_URL, false);
|
|
}
|
|
|
|
/**
|
|
* @dev Internal table-agnostic conversion
|
|
*/
|
|
function _encode(bytes memory data, string memory table, bool withPadding) private pure returns (string memory) {
|
|
/**
|
|
* Inspired by Brecht Devos (Brechtpd) implementation - MIT licence
|
|
* https://github.com/Brechtpd/base64/blob/e78d9fd951e7b0977ddca77d92dc85183770daf4/base64.sol
|
|
*/
|
|
if (data.length == 0) return "";
|
|
|
|
// If padding is enabled, the final length should be `bytes` data length divided by 3 rounded up and then
|
|
// multiplied by 4 so that it leaves room for padding the last chunk
|
|
// - `data.length + 2` -> Round up
|
|
// - `/ 3` -> Number of 3-bytes chunks
|
|
// - `4 *` -> 4 characters for each chunk
|
|
// If padding is disabled, the final length should be `bytes` data length multiplied by 4/3 rounded up as
|
|
// opposed to when padding is required to fill the last chunk.
|
|
// - `4 *` -> 4 characters for each chunk
|
|
// - `data.length + 2` -> Round up
|
|
// - `/ 3` -> Number of 3-bytes chunks
|
|
uint256 resultLength = withPadding ? 4 * ((data.length + 2) / 3) : (4 * data.length + 2) / 3;
|
|
|
|
string memory result = new string(resultLength);
|
|
|
|
/// @solidity memory-safe-assembly
|
|
assembly {
|
|
// Prepare the lookup table (skip the first "length" byte)
|
|
let tablePtr := add(table, 1)
|
|
|
|
// Prepare result pointer, jump over length
|
|
let resultPtr := add(result, 32)
|
|
|
|
// Run over the input, 3 bytes at a time
|
|
for {
|
|
let dataPtr := data
|
|
let endPtr := add(data, mload(data))
|
|
} lt(dataPtr, endPtr) {
|
|
|
|
} {
|
|
// Advance 3 bytes
|
|
dataPtr := add(dataPtr, 3)
|
|
let input := mload(dataPtr)
|
|
|
|
// To write each character, shift the 3 bytes (18 bits) chunk
|
|
// 4 times in blocks of 6 bits for each character (18, 12, 6, 0)
|
|
// and apply logical AND with 0x3F which is the number of
|
|
// the previous character in the ASCII table prior to the Base64 Table
|
|
// The result is then added to the table to get the character to write,
|
|
// and finally write it in the result pointer but with a left shift
|
|
// of 256 (1 byte) - 8 (1 ASCII char) = 248 bits
|
|
|
|
mstore8(resultPtr, mload(add(tablePtr, and(shr(18, input), 0x3F))))
|
|
resultPtr := add(resultPtr, 1) // Advance
|
|
|
|
mstore8(resultPtr, mload(add(tablePtr, and(shr(12, input), 0x3F))))
|
|
resultPtr := add(resultPtr, 1) // Advance
|
|
|
|
mstore8(resultPtr, mload(add(tablePtr, and(shr(6, input), 0x3F))))
|
|
resultPtr := add(resultPtr, 1) // Advance
|
|
|
|
mstore8(resultPtr, mload(add(tablePtr, and(input, 0x3F))))
|
|
resultPtr := add(resultPtr, 1) // Advance
|
|
}
|
|
|
|
if withPadding {
|
|
// When data `bytes` is not exactly 3 bytes long
|
|
// it is padded with `=` characters at the end
|
|
switch mod(mload(data), 3)
|
|
case 1 {
|
|
mstore8(sub(resultPtr, 1), 0x3d)
|
|
mstore8(sub(resultPtr, 2), 0x3d)
|
|
}
|
|
case 2 {
|
|
mstore8(sub(resultPtr, 1), 0x3d)
|
|
}
|
|
}
|
|
}
|
|
|
|
return result;
|
|
}
|
|
}
|
|
|