You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
372 lines
16 KiB
372 lines
16 KiB
pragma solidity ^0.6.0;
|
|
|
|
import "../../GSN/Context.sol";
|
|
import "./IERC721.sol";
|
|
import "./IERC721Receiver.sol";
|
|
import "../../math/SafeMath.sol";
|
|
import "../../utils/Address.sol";
|
|
import "../../utils/Counters.sol";
|
|
import "../../introspection/ERC165.sol";
|
|
|
|
/**
|
|
* @title ERC721 Non-Fungible Token Standard basic implementation
|
|
* @dev see https://eips.ethereum.org/EIPS/eip-721
|
|
*/
|
|
contract ERC721 is Context, ERC165, IERC721 {
|
|
using SafeMath for uint256;
|
|
using Address for address;
|
|
using Counters for Counters.Counter;
|
|
|
|
// Equals to `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))`
|
|
// which can be also obtained as `IERC721Receiver(0).onERC721Received.selector`
|
|
bytes4 private constant _ERC721_RECEIVED = 0x150b7a02;
|
|
|
|
// Mapping from token ID to owner
|
|
mapping (uint256 => address) private _tokenOwner;
|
|
|
|
// Mapping from token ID to approved address
|
|
mapping (uint256 => address) private _tokenApprovals;
|
|
|
|
// Mapping from owner to number of owned token
|
|
mapping (address => Counters.Counter) private _ownedTokensCount;
|
|
|
|
// Mapping from owner to operator approvals
|
|
mapping (address => mapping (address => bool)) private _operatorApprovals;
|
|
|
|
/*
|
|
* bytes4(keccak256('balanceOf(address)')) == 0x70a08231
|
|
* bytes4(keccak256('ownerOf(uint256)')) == 0x6352211e
|
|
* bytes4(keccak256('approve(address,uint256)')) == 0x095ea7b3
|
|
* bytes4(keccak256('getApproved(uint256)')) == 0x081812fc
|
|
* bytes4(keccak256('setApprovalForAll(address,bool)')) == 0xa22cb465
|
|
* bytes4(keccak256('isApprovedForAll(address,address)')) == 0xe985e9c5
|
|
* bytes4(keccak256('transferFrom(address,address,uint256)')) == 0x23b872dd
|
|
* bytes4(keccak256('safeTransferFrom(address,address,uint256)')) == 0x42842e0e
|
|
* bytes4(keccak256('safeTransferFrom(address,address,uint256,bytes)')) == 0xb88d4fde
|
|
*
|
|
* => 0x70a08231 ^ 0x6352211e ^ 0x095ea7b3 ^ 0x081812fc ^
|
|
* 0xa22cb465 ^ 0xe985e9c ^ 0x23b872dd ^ 0x42842e0e ^ 0xb88d4fde == 0x80ac58cd
|
|
*/
|
|
bytes4 private constant _INTERFACE_ID_ERC721 = 0x80ac58cd;
|
|
|
|
constructor () public {
|
|
// register the supported interfaces to conform to ERC721 via ERC165
|
|
_registerInterface(_INTERFACE_ID_ERC721);
|
|
}
|
|
|
|
/**
|
|
* @dev Gets the balance of the specified address.
|
|
* @param owner address to query the balance of
|
|
* @return uint256 representing the amount owned by the passed address
|
|
*/
|
|
function balanceOf(address owner) public view override returns (uint256) {
|
|
require(owner != address(0), "ERC721: balance query for the zero address");
|
|
|
|
return _ownedTokensCount[owner].current();
|
|
}
|
|
|
|
/**
|
|
* @dev Gets the owner of the specified token ID.
|
|
* @param tokenId uint256 ID of the token to query the owner of
|
|
* @return address currently marked as the owner of the given token ID
|
|
*/
|
|
function ownerOf(uint256 tokenId) public view override returns (address) {
|
|
address owner = _tokenOwner[tokenId];
|
|
require(owner != address(0), "ERC721: owner query for nonexistent token");
|
|
|
|
return owner;
|
|
}
|
|
|
|
/**
|
|
* @dev Approves another address to transfer the given token ID
|
|
* The zero address indicates there is no approved address.
|
|
* There can only be one approved address per token at a given time.
|
|
* Can only be called by the token owner or an approved operator.
|
|
* @param to address to be approved for the given token ID
|
|
* @param tokenId uint256 ID of the token to be approved
|
|
*/
|
|
function approve(address to, uint256 tokenId) public virtual override {
|
|
address owner = ownerOf(tokenId);
|
|
require(to != owner, "ERC721: approval to current owner");
|
|
|
|
require(_msgSender() == owner || isApprovedForAll(owner, _msgSender()),
|
|
"ERC721: approve caller is not owner nor approved for all"
|
|
);
|
|
|
|
_approve(to, tokenId);
|
|
}
|
|
|
|
/**
|
|
* @dev Gets the approved address for a token ID, or zero if no address set
|
|
* Reverts if the token ID does not exist.
|
|
* @param tokenId uint256 ID of the token to query the approval of
|
|
* @return address currently approved for the given token ID
|
|
*/
|
|
function getApproved(uint256 tokenId) public view override returns (address) {
|
|
require(_exists(tokenId), "ERC721: approved query for nonexistent token");
|
|
|
|
return _tokenApprovals[tokenId];
|
|
}
|
|
|
|
/**
|
|
* @dev Sets or unsets the approval of a given operator
|
|
* An operator is allowed to transfer all tokens of the sender on their behalf.
|
|
* @param operator operator address to set the approval
|
|
* @param approved representing the status of the approval to be set
|
|
*/
|
|
function setApprovalForAll(address operator, bool approved) public virtual override {
|
|
require(operator != _msgSender(), "ERC721: approve to caller");
|
|
|
|
_operatorApprovals[_msgSender()][operator] = approved;
|
|
emit ApprovalForAll(_msgSender(), operator, approved);
|
|
}
|
|
|
|
/**
|
|
* @dev Tells whether an operator is approved by a given owner.
|
|
* @param owner owner address which you want to query the approval of
|
|
* @param operator operator address which you want to query the approval of
|
|
* @return bool whether the given operator is approved by the given owner
|
|
*/
|
|
function isApprovedForAll(address owner, address operator) public view override returns (bool) {
|
|
return _operatorApprovals[owner][operator];
|
|
}
|
|
|
|
/**
|
|
* @dev Transfers the ownership of a given token ID to another address.
|
|
* Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
|
|
* Requires the msg.sender to be the owner, approved, or operator.
|
|
* @param from current owner of the token
|
|
* @param to address to receive the ownership of the given token ID
|
|
* @param tokenId uint256 ID of the token to be transferred
|
|
*/
|
|
function transferFrom(address from, address to, uint256 tokenId) public virtual override {
|
|
//solhint-disable-next-line max-line-length
|
|
require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
|
|
|
|
_transferFrom(from, to, tokenId);
|
|
}
|
|
|
|
/**
|
|
* @dev Safely transfers the ownership of a given token ID to another address
|
|
* If the target address is a contract, it must implement {IERC721Receiver-onERC721Received},
|
|
* which is called upon a safe transfer, and return the magic value
|
|
* `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))`; otherwise,
|
|
* the transfer is reverted.
|
|
* Requires the msg.sender to be the owner, approved, or operator
|
|
* @param from current owner of the token
|
|
* @param to address to receive the ownership of the given token ID
|
|
* @param tokenId uint256 ID of the token to be transferred
|
|
*/
|
|
function safeTransferFrom(address from, address to, uint256 tokenId) public virtual override {
|
|
safeTransferFrom(from, to, tokenId, "");
|
|
}
|
|
|
|
/**
|
|
* @dev Safely transfers the ownership of a given token ID to another address
|
|
* If the target address is a contract, it must implement {IERC721Receiver-onERC721Received},
|
|
* which is called upon a safe transfer, and return the magic value
|
|
* `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))`; otherwise,
|
|
* the transfer is reverted.
|
|
* Requires the _msgSender() to be the owner, approved, or operator
|
|
* @param from current owner of the token
|
|
* @param to address to receive the ownership of the given token ID
|
|
* @param tokenId uint256 ID of the token to be transferred
|
|
* @param _data bytes data to send along with a safe transfer check
|
|
*/
|
|
function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory _data) public virtual override {
|
|
require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
|
|
_safeTransferFrom(from, to, tokenId, _data);
|
|
}
|
|
|
|
/**
|
|
* @dev Safely transfers the ownership of a given token ID to another address
|
|
* If the target address is a contract, it must implement `onERC721Received`,
|
|
* which is called upon a safe transfer, and return the magic value
|
|
* `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))`; otherwise,
|
|
* the transfer is reverted.
|
|
* Requires the msg.sender to be the owner, approved, or operator
|
|
* @param from current owner of the token
|
|
* @param to address to receive the ownership of the given token ID
|
|
* @param tokenId uint256 ID of the token to be transferred
|
|
* @param _data bytes data to send along with a safe transfer check
|
|
*/
|
|
function _safeTransferFrom(address from, address to, uint256 tokenId, bytes memory _data) internal virtual {
|
|
_transferFrom(from, to, tokenId);
|
|
require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
|
|
}
|
|
|
|
/**
|
|
* @dev Returns whether the specified token exists.
|
|
* @param tokenId uint256 ID of the token to query the existence of
|
|
* @return bool whether the token exists
|
|
*/
|
|
function _exists(uint256 tokenId) internal view returns (bool) {
|
|
address owner = _tokenOwner[tokenId];
|
|
return owner != address(0);
|
|
}
|
|
|
|
/**
|
|
* @dev Returns whether the given spender can transfer a given token ID.
|
|
* @param spender address of the spender to query
|
|
* @param tokenId uint256 ID of the token to be transferred
|
|
* @return bool whether the msg.sender is approved for the given token ID,
|
|
* is an operator of the owner, or is the owner of the token
|
|
*/
|
|
function _isApprovedOrOwner(address spender, uint256 tokenId) internal view returns (bool) {
|
|
require(_exists(tokenId), "ERC721: operator query for nonexistent token");
|
|
address owner = ownerOf(tokenId);
|
|
return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender));
|
|
}
|
|
|
|
/**
|
|
* @dev Internal function to safely mint a new token.
|
|
* Reverts if the given token ID already exists.
|
|
* If the target address is a contract, it must implement `onERC721Received`,
|
|
* which is called upon a safe transfer, and return the magic value
|
|
* `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))`; otherwise,
|
|
* the transfer is reverted.
|
|
* @param to The address that will own the minted token
|
|
* @param tokenId uint256 ID of the token to be minted
|
|
*/
|
|
function _safeMint(address to, uint256 tokenId) internal virtual {
|
|
_safeMint(to, tokenId, "");
|
|
}
|
|
|
|
/**
|
|
* @dev Internal function to safely mint a new token.
|
|
* Reverts if the given token ID already exists.
|
|
* If the target address is a contract, it must implement `onERC721Received`,
|
|
* which is called upon a safe transfer, and return the magic value
|
|
* `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))`; otherwise,
|
|
* the transfer is reverted.
|
|
* @param to The address that will own the minted token
|
|
* @param tokenId uint256 ID of the token to be minted
|
|
* @param _data bytes data to send along with a safe transfer check
|
|
*/
|
|
function _safeMint(address to, uint256 tokenId, bytes memory _data) internal virtual {
|
|
_mint(to, tokenId);
|
|
require(_checkOnERC721Received(address(0), to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
|
|
}
|
|
|
|
/**
|
|
* @dev Internal function to mint a new token.
|
|
* Reverts if the given token ID already exists.
|
|
* @param to The address that will own the minted token
|
|
* @param tokenId uint256 ID of the token to be minted
|
|
*/
|
|
function _mint(address to, uint256 tokenId) internal virtual {
|
|
require(to != address(0), "ERC721: mint to the zero address");
|
|
require(!_exists(tokenId), "ERC721: token already minted");
|
|
|
|
_beforeTokenTransfer(address(0), to, tokenId);
|
|
|
|
_tokenOwner[tokenId] = to;
|
|
_ownedTokensCount[to].increment();
|
|
|
|
emit Transfer(address(0), to, tokenId);
|
|
}
|
|
|
|
/**
|
|
* @dev Internal function to burn a specific token.
|
|
* Reverts if the token does not exist.
|
|
* @param tokenId uint256 ID of the token being burned
|
|
*/
|
|
function _burn(uint256 tokenId) internal virtual {
|
|
address owner = ownerOf(tokenId);
|
|
|
|
_beforeTokenTransfer(owner, address(0), tokenId);
|
|
|
|
// Clear approvals
|
|
_approve(address(0), tokenId);
|
|
|
|
_ownedTokensCount[owner].decrement();
|
|
_tokenOwner[tokenId] = address(0);
|
|
|
|
emit Transfer(owner, address(0), tokenId);
|
|
}
|
|
|
|
/**
|
|
* @dev Internal function to transfer ownership of a given token ID to another address.
|
|
* As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
|
|
* @param from current owner of the token
|
|
* @param to address to receive the ownership of the given token ID
|
|
* @param tokenId uint256 ID of the token to be transferred
|
|
*/
|
|
function _transferFrom(address from, address to, uint256 tokenId) internal virtual {
|
|
require(ownerOf(tokenId) == from, "ERC721: transfer of token that is not own");
|
|
require(to != address(0), "ERC721: transfer to the zero address");
|
|
|
|
_beforeTokenTransfer(from, to, tokenId);
|
|
|
|
// Clear approvals
|
|
_approve(address(0), tokenId);
|
|
|
|
_ownedTokensCount[from].decrement();
|
|
_ownedTokensCount[to].increment();
|
|
|
|
_tokenOwner[tokenId] = to;
|
|
|
|
emit Transfer(from, to, tokenId);
|
|
}
|
|
|
|
/**
|
|
* @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
|
|
* The call is not executed if the target address is not a contract.
|
|
*
|
|
* @param from address representing the previous owner of the given token ID
|
|
* @param to target address that will receive the tokens
|
|
* @param tokenId uint256 ID of the token to be transferred
|
|
* @param _data bytes optional data to send along with the call
|
|
* @return bool whether the call correctly returned the expected magic value
|
|
*/
|
|
function _checkOnERC721Received(address from, address to, uint256 tokenId, bytes memory _data)
|
|
private returns (bool)
|
|
{
|
|
if (!to.isContract()) {
|
|
return true;
|
|
}
|
|
// solhint-disable-next-line avoid-low-level-calls
|
|
(bool success, bytes memory returndata) = to.call(abi.encodeWithSelector(
|
|
IERC721Receiver(to).onERC721Received.selector,
|
|
_msgSender(),
|
|
from,
|
|
tokenId,
|
|
_data
|
|
));
|
|
if (!success) {
|
|
if (returndata.length > 0) {
|
|
// solhint-disable-next-line no-inline-assembly
|
|
assembly {
|
|
let returndata_size := mload(returndata)
|
|
revert(add(32, returndata), returndata_size)
|
|
}
|
|
} else {
|
|
revert("ERC721: transfer to non ERC721Receiver implementer");
|
|
}
|
|
} else {
|
|
bytes4 retval = abi.decode(returndata, (bytes4));
|
|
return (retval == _ERC721_RECEIVED);
|
|
}
|
|
}
|
|
|
|
function _approve(address to, uint256 tokenId) private {
|
|
_tokenApprovals[tokenId] = to;
|
|
emit Approval(ownerOf(tokenId), to, tokenId);
|
|
}
|
|
|
|
/**
|
|
* @dev Hook that is called before any token transfer. This includes minting
|
|
* and burning.
|
|
*
|
|
* Calling conditions:
|
|
*
|
|
* - when `from` and `to` are both non-zero, `from`'s `tokenId` will be
|
|
* transferred to `to`.
|
|
* - when `from` is zero, `tokenId` will be minted for `to`.
|
|
* - when `to` is zero, `from`'s `tokenId` will be burned.
|
|
* - `from` and `to` are never both zero.
|
|
*
|
|
* To learn more about hooks, head to xref:ROOT:using-hooks.adoc[Using Hooks].
|
|
*/
|
|
function _beforeTokenTransfer(address from, address to, uint256 tokenId) internal virtual { }
|
|
}
|
|
|